こんばんは、晋作さん。ピラルクです。
(インデントミスで一度削除しました)
> 質問1.DataGridのプロパティをテキストからHyperLinkに
> 変更することって可能なのでしょうか？
> と書きましたが、変更ではなく、最初からHyperLinkにしたいです。
おおよそ以下のようになりますが、これだとセルをマウスで１回ついて
編集対象にし、さらに付いてリンクとなります。このあたりはキーボード
での挙動もからんでいるので、仕様としてどうあるべきかをきっちり
まとめる必要があると思われます。
'--------+---------+---------+---------*---------+---------+---------+----
Private Sub Form1_Load(ByVal sender As System.Object, _
ByVal e As System.EventArgs) Handles MyBase.Load
'DataTable
Dim dt As New DataTable()
dt.Columns.Add("列名A", GetType(String))
dt.Columns.Add("列名B", GetType(String))
'DataTableにダミーDataを10行作成
Dim i As Integer
Dim dr As DataRow
While (i < 10)
dr = dt.NewRow
dr(0) = "Data_A:" & i
If i Mod 2 = 0 Then
dr(1) = "□http://dobon.net/"
Else
dr(1) = "■http://dobon.net/card/index.html"
End If
dt.Rows.Add(dr)
i += 1
End While
'ColumnStyle 列0 (普通のText列)
Dim colA As DataGridColumnStyle = New DataGridTextBoxColumn()
colA.HeaderText = "見出しA"
colA.MappingName = "列名A"
colA.Width = 60
'ColumnStyle 列1 (HyperLink列)
Dim colB As DataGridColumnStyle = New DataGridLinkLabelColumn()
colB.HeaderText = "見出しB"
colB.MappingName = "列名B"
colB.Width = 180
'TableStyleにColumnStyleを設定
Dim ts As New DataGridTableStyle()
ts.GridColumnStyles.Add(colA)
ts.GridColumnStyles.Add(colB)
'DataGridにTableStyleとDataTableを設定
DataGrid1.TableStyles.Add(ts)
DataGrid1.DataSource = New DataView(dt)
End Sub
End Class
'--------+---------+---------+---------*---------+---------+---------+----
'HyperLink列用の特注ColumnStyle
Public Class DataGridLinkLabelColumn
Inherits DataGridColumnStyle
'Edit時(編集時)に使いまわしされるLinkLabel
Private m_linkLabel As New LinkLabel()
Public Sub New()
m_linkLabel.Visible = False
AddHandler m_linkLabel.LinkClicked, AddressOf LinkLabel_LinkClicked
End Sub
Private Sub LinkLabel_LinkClicked(ByVal sender As System.Object, _
ByVal e As System.Windows.Forms.LinkLabelLinkClickedEventArgs)
Dim url As New Uri(m_linkLabel.Text.Substring(1))
'TODO:ここにHyperLinkの処理を記述
End Sub
Protected Overrides Sub Abort(ByVal rowNum As Integer)
Invalidate()
End Sub
'編集後の値をModelに返すためだが、Linkは編集しないので実装不要
'しかし、Link済みなどのstatusをModelで保管させるなら、これは役に立つ
Protected Overrides Function Commit( _
ByVal dataSource As CurrencyManager, _
ByVal rowNum As Integer) As Boolean
Return True
End Function
'これがないと編集時にControlが表示されないので注意
Protected Overrides Sub SetDataGridInColumn(ByVal value As DataGrid)
MyBase.SetDataGridInColumn(value)
If Not (m_linkLabel.Parent Is Nothing) Then
m_linkLabel.Parent.Controls.Remove(m_linkLabel)
End If
If Not (value Is Nothing) Then
value.Controls.Add(m_linkLabel)
End If
End Sub
'MustOverrideなPaint Method
Protected Overloads Overrides Sub Paint(ByVal g As Graphics, _
ByVal bounds As Rectangle, _
ByVal [source] As CurrencyManager, _
ByVal rowNum As Integer)
Paint(g, bounds, [source], rowNum, False)
End Sub
Protected Overloads Overrides Sub Paint(ByVal g As Graphics, _
ByVal bounds As Rectangle, _
ByVal [source] As CurrencyManager, _
ByVal rowNum As Integer, _
ByVal alignToRight As Boolean)
Dim val As String = CType(GetColumnValueAtRow([source], rowNum), String)
Dim backColorBrush As New SolidBrush(DataGridTableStyle.BackColor)
Dim foreColorBrush As Brush
Dim valFont As Font
'HyperLinkの有効無効によりフォント・カラーを変える
If val.StartsWith("□") Then
valFont = New Font(DataGridTableStyle.DataGrid.Font, FontStyle.Underline)
foreColorBrush = SystemBrushes.HotTrack
Else
valFont = DataGridTableStyle.DataGrid.Font
foreColorBrush = Brushes.DarkGray
End If
'セル描画処理
g.FillRectangle(backColorBrush, bounds)
bounds.Offset(2, 2)
g.DrawString(val, valFont, foreColorBrush, _
RectangleF.FromLTRB(bounds.X, bounds.Y, bounds.Right, bounds.Bottom))
'm_linkLabelに描画をまかしたいが、それは無理みたい。
'レンダラーは高速でなければならないというDataGridの設計思想かな。
'これのせいで、セルのカスタマイズに関してはJTableの方がまだ分かり良いと思う。。。
'm_linkLabelも継承で作っておき、PaintにDispatchさせてGraphicsに描かせる
'ことをすれば可能かもしれないが、LinkLabel程度なら描画の負担もないので
'そんなややこしいことに挑戦しなくても問題ないと思われる。
End Sub
'MustOverrideなEdit Method
Protected Overloads Overrides Sub Edit(ByVal [source] As CurrencyManager, _
ByVal rowNum As Integer, _
ByVal bounds As Rectangle, _
ByVal [readOnly] As Boolean, _
ByVal instantText As String, _
ByVal cellIsVisible As Boolean)
Dim val As String = CType(GetColumnValueAtRow([source], rowNum), String)
'HyperLink無効時は無視
If val.StartsWith("□") Then
m_linkLabel.Visible = cellIsVisible
Else
m_linkLabel.Visible = False
End If
'HyperLink有効時は編集セルにm_linkLabelを配置
If m_linkLabel.Visible Then
m_linkLabel.Bounds = New Rectangle(bounds.X + 2, bounds.Y + 2, _
bounds.Width - 4, bounds.Height - 4)
m_linkLabel.Text = val
m_linkLabel.Visible = True
DataGridTableStyle.DataGrid.Invalidate(bounds)
End If
End Sub
'以下はサイズ関連のMustOverrideなMethod
Protected Overrides Function GetPreferredSize( _
ByVal g As Graphics, _
ByVal value As Object) As Size
Return New Size(100, GetMinimumHeight())
End Function
Protected Overrides Function GetPreferredHeight( _
ByVal g As Graphics, _
ByVal value As Object) As Integer
Return GetMinimumHeight()
End Function
Protected Overrides Function GetMinimumHeight() As Integer
Return m_linkLabel.PreferredHeight + 5
End Function
End Class
> 質問2.他のTipsを参考にしたとき
> Dim ts As New DataGridTableStyle() と記入すると、
> 「'型'DataGridTableStyle'が定義されていません。」とエラーになります。
> 何故でしょうか？
プロジェクト名を"DataGridTableStyle"にしたとか。
テーブルのデータをそのまま表示するDataGridの使い方は知っていますが、
データの値によって、■や□を表示させ、なお且つリンクをはりたいと思います。
データの値が1だったら■、0だったら□、表示させ、
パラメタ付きのHyperLinkを作成したいのです。
そういう場合はどのようにすれば良いのでしょうか？
DataGridのプロパティをテキストからHyperLinkに
変更することって可能なのでしょうか？
まだまだ初心者ですが、よろしくお願いします。