DOBON.NETプログラミング道掲示板

■35324 / 8階層)  複数のPictureBox画像を複数のファイルへ保存したい
□投稿者/ 魔界の仮面弁士 大御所(1516回)-(2023/01/12(Thu) 16:00:58)
  • アイコンNo35323に返信(ま〜さんの記事)
    > 本題ですが先のコードでわDisposeした方が良いのか程度で書いてました
    でわ→では


    > If PictureBox16.Image IsNot Nothing Then
    >   PictureBox16.Image.Dispose()
    > End If
    上記は『PictureBox16.Image?.Dispose()』の一行で書けます。
    https://learn.microsoft.com/ja-jp/dotnet/visual-basic/language-reference/operators/null-conditional-operators

    そして、Disposed 状態のオブジェクトを参照し続けた状態にするのは問題があるため、
    PictureBox16.Image には直ちに、Nothing (あるいは別の画像)を代入しなおさねばなりません。

    ただし本来は、別の画像(あるいはNothing)を割り当ててから元の画像を Dispose した方が望ましいです。


    > PictureBox16.Image = bmp ← 自動生成されたイメージが入っている
    > Picture(PageNo).Image = PictureBox16.Image
    > これは同じ画像を各PictureBoxへ書いたと同じ扱いになりますか?

    一つの画像を複数の PictureBox から参照している状態になりますね。


    つまり、一枚の絵画を複数人で同時に鑑賞している状態に相当します。
    ということは、その絵画を破損させれば、他の閲覧者も破損した絵画を見ることになってしまいます。
    もしも閲覧者A が、自身が見ている絵画を破棄したとすれば、
    それは閲覧者B や C が見ている絵画も捨てられたことを意味します。

    Picture(0).Image を Dispose() した場合、
    Picture(1).Image も破棄されるので、ArgumentException 等になってしまう所以です。


    しかしあらかじめ、一枚の元絵を人数分複製しておき、それを閲覧させるようにすれば、
    元絵を破損させたとしても、各閲覧者の見ている画像が見えなくなることはありません。

    これはすなわち、
     Picture(PageNo).Image = DirectCast(PictureBox16.Image?.Clone(), Image)
    のようにしておく、ということです。それぞれの画像は元絵の複製にすぎないわけですから、
    Picture(0).Image を Dispose() したとしても、
    Picture(1).Image や PictureBox16.Image には影響がありません。


    > 一旦PictureBox16経由で各PictureBoxへ作画されています
    > これがやっては駄目な事でしょうか?
    何を経由させても構いません。
    変数であろうと PictureBox16.Image であろうと大丈夫です。

    問題になっているのは、PictureBox16 を経由させたことではなく、
    「使用中のオブジェクトを Dispose したこと」です。


    Picture(0) がその画像を使わなくなったとしても、他の PictureBox が
    同じインスタンスを使用しているのなら、Dispose してはいけません。
    捨てるなら、「誰も使わなくなってから」にしましょう。



    > ―――――――Bエラーになる箇所――――――――――
    > Picture(PageNo).Image.Save(PicturePath"MojiGAZou1.bmp",System.Drawing.Imaging.ImageFormat.Bmp)
    そもそも文法違反になるでしょうね。(^_^;)


    > Imageは使わない方がよいのでしょうか?
    いいえ。「誰かが使用している最中の Image を勝手に Dispose してはいけない」というだけです。

    「使い終わった Image は Dispose しなければならない」ルールであるのは確かですが、
    「私が使い終わったので、他の人が使っていたとしても勝手に捨ててしまおう」はルール違反です。


    > Dim Picture() As PictureBox = {PictureBox1, PictureBox2, PictureBox3, PictureBox4, PictureBox5}
    > For i As Byte = 0 To 4
    配列のインデックスは常に Integer 型です。Byte 型ではありません。

    Byte/SByte/Short/UShort は Integer 型への暗黙変換が可能なのでエラーにはなりませんが、
    わざわざ Byte 型を経由させると、無駄な変換処理が増えることになってしまいます。

    そのため普通は As Byte とはせず、「For i = 0 To 4」もしくは「For i As Integer = 0 To 4」と書きます。


    > Picture(i).Size = New Size(Picture(i).Size.Width, 320)
    > Picture(i).Size = New Size(Picture(i).Size.Height, 160)

    これって、
     Picture(i).Width = Picture(i).Size.Width
     Picture(i).Height = 320
     Picture(i).Width = Picture(i).Size.Height
     Picture(i).Height = 160
    に相当する処理ですよね。何故こんなことを…?

    幅と高さを指定するだけならば、
     Picture(i).Size = New Size(320, 160)
    では駄目なのでしょうか。SizeMode 指定のために必要だったとか?

    > Picture(i).Image = Image.FromFile(PicturePath + "MojiGAZou" & CStr(i + 1) & ".bmp")
    前 1 つが「+ 演算子」で、
    後 2 つが「& 演算子」なのは何故ですか?


    > Me.PictureBox1.Image.Save(PicturePath + "MojiGAZou1.bmp", System.Drawing.Imaging.ImageFormat.Bmp)
    > Me.PictureBox2.Image.Save(PicturePath + "MojiGAZou2.bmp", System.Drawing.Imaging.ImageFormat.Bmp)
    > Me.PictureBox3.Image.Save(PicturePath + "MojiGAZou3.bmp", System.Drawing.Imaging.ImageFormat.Bmp)
    > Me.PictureBox4.Image.Save(PicturePath + "MojiGAZou4.bmp", System.Drawing.Imaging.ImageFormat.Bmp)
    > Me.PictureBox5.Image.Save(PicturePath + "MojiGAZou5.bmp", System.Drawing.Imaging.ImageFormat.Bmp)
    > これもPictureBox1.のSaveの所でエラーとなります。こんな事は出来ない?

    「Image が Dispose されていない」かつ「指定のパスに書き込みが可能」な状態にしておけば
    上記のコードでもエラーにはならないと思いますよ。

    仮に Dispose していなかったとしても、その画像が Image.FromFile で読み込まれていて、
    かつ、そのインスタンスがまだ破棄されていなかったとしたら、ファイルがロックされたままになるので
    また別のエラーを誘発する可能性がありますね。


    >> PictureBox1.Image?.Dispose() '処分
    >> PictureBox1.Image = Nothing '解放
    > とありますがこれはどの様な意味ですか?

    If PictureBox1.Image IsNot Nothing Then
     PictureBox1.Image.Dispose() '処分
    End If
    PictureBox1.Image = Nothing '解放

    という意味です。

    KOZ さんの書かれた No35282 の場合は、
     Dim bmp = CreateBitmapFromControl(RichTextBox1)
     If PictureBox1.Image IsNot Nothing Then
       PictureBox1.Image.Dispose()
     End If
     PictureBox1.Image = bmp
    ですね。

    いずれも、「bmp (または Nothing)を参照させる前に、以前の画像があれば Dispose する」という処理です。
    以前の画像を「処分してから解放」の順序になっているので、本当は「解放してから処分」の方が良いのですが。

    上記 No35282 のコードを「解放してから処分」にするのであれば
     Using PictureBox1.Image
      PictureBox1.Image = CreateBitmapFromControl(RichTextBox1)
     End Using
    または
     Dim oldImage = PictureBox1.Image
     PictureBox1.Image = CreateBitmapFromControl(RichTextBox1)
     oldImage?.Dispose()
    と書きます。自分は後者の方が好みですが、 No35282 のままでも問題はありません。
違反を報告
削除キー/

前の記事(元になった記事) 次の記事(この記事の返信)
←Re[7]: 複数のPictureBox画像を複数のファイルへ保存したい /ま〜 →Re[9]: 複数のPictureBox画像を複数のファイルへ保存したい /ま〜
 
上記関連ツリー

Nomalアイコン PictureBoxの画像を連続保存 / ま〜 (23/01/10(Tue) 19:41) #35316
Nomalアイコン Re[1]: PictureBoxの画像を連続保存 / 魔界の仮面弁士 (23/01/10(Tue) 20:23) #35317
  └Nomalアイコン Re[2]: PictureBoxの画像を連続保存 / ま〜 (23/01/11(Wed) 13:59) #35318
    └Nomalアイコン Re[3]: PictureBoxの画像を連続保存 / 魔界の仮面弁士 (23/01/11(Wed) 14:06) #35319
      └Nomalアイコン Re[4]: PictureBoxの画像を連続保存 / ま〜 (23/01/11(Wed) 16:06) #35320
        └Nomalアイコン Re[5]: PictureBoxの画像を連続保存 / ま〜 (23/01/11(Wed) 16:49) #35321
          └Nomalアイコン Re[6]: PictureBoxの画像を連続保存 / 魔界の仮面弁士 (23/01/11(Wed) 17:36) #35322
            └Nomalアイコン Re[7]: 複数のPictureBox画像を複数のファイルへ保存したい / ま〜 (23/01/12(Thu) 14:13) #35323
              └Nomalアイコン 複数のPictureBox画像を複数のファイルへ保存したい / 魔界の仮面弁士 (23/01/12(Thu) 16:00) #35324 ←Now
                └Nomalアイコン Re[9]: 複数のPictureBox画像を複数のファイルへ保存したい / ま〜 (23/01/16(Mon) 14:20) #35330
                  └Nomalアイコン Re[10]: 複数のPictureBox画像を複数のファイルへ保存したい / 魔界の仮面弁士 (23/01/16(Mon) 16:14) #35331
                    └Nomalアイコン Re[11]: 複数のPictureBox画像を複数のファイルへ保存したい / ま〜 (23/01/20(Fri) 12:55) #35340 解決み!

All 上記ツリーを一括表示 / 上記ツリーをトピック表示
 
上記の記事へ返信

Mode/  Pass/


- Child Tree -