■No35113に返信(よっし〜さんの記事)
> 現在も親の上に半透明シート（？）を表示させ、その上にLabelを配置したフォームを表示させております。

半透明シートを被せて、下の親フォームを操作不能にしたいという意図でしょうか。

であれば、親フォームにフォームサイズの Panel を全体表示しておき、
その Panel の背景に、親フォームの内容を描画してはどうでしょう。


(1) 親フォームに Panel1 を配置。これが半透明モドキになる。
　Panel1 は普段、Visible = False にしておく。

(2) その Panel1 内に、子コントロールとして黄色の Panel2 を置き、
　Panel2 内に Label1 や Button1 を置く。
　Button1_Click のイベントにて「Panel1.Hide()」を記述。

(3) 半透明表示のために、以下を実行。

'Panel1 は Visible = False な状態で開始する事
Panel1.Visible = False

Dim cr = Me.ClientRectangle
Dim r = Me.RectangleToScreen(cr)
Dim bmp As New Bitmap(cr.Width, cr.Height)
Using g = Graphics.FromImage(bmp)
    '画面キャプチャ
    g.CopyFromScreen(r.Location, New Point(0, 0), r.Size)
    '半透明のスモークをかける
    Using b As New SolidBrush(Color.FromArgb(180, Color.DarkSlateGray))
        g.FillRectangle(b, cr)
    End Using
End Using

'Panel1を重ねて表示
Dim oldBmp = Panel1.BackgroundImage
Panel1.BackgroundImage = bmp
If oldBmp IsNot Nothing Then
    oldBmp.Dispose()
End If
Panel1.BringToFront()
Panel1.SetBounds(cr.X, cr.Y, cr.Width, cr.Height)
Panel1.Visible = True

■No35109に返信(魔界の仮面弁士さんの記事)
> ■No35108に返信(よっし〜さんの記事)
>>ここで言うBホームの左上とは「AフォームのClientSizeの０，０の位置」です。
> rect = targetForm.RectangleToScreen(targetForm.ClientRectangle)
> でスクリーン座標が得られそうですが、これでは駄目でしょうか。

魔界の仮面弁士様、早速のご教示頂きまして有り難うございます。

お教え頂いた内容ですが・・・完璧でございます。

        Dim A As Rectangle = Oya.RectangleToScreen(Oya.ClientRectangle)
        Me.Location = New Point(A.Left, A.Top)
        Me.Size = New Size(A.Width, A.Height)

どうも有り難うございました。

魔界の仮面弁士様
いつも丁寧がご指導ありがとうございます。

折角教えて頂いたのですが、私の理解力が追いつきません。
CommandBuilderで、CommandTextを取得した時にに設定されるParameterのプロパティは次のようになっています。
DeleteCommanndのみ記載
Paramete
Name	DbType	OleDbType	SourceColumn	Direction	SourceVersion	Value
p1	Int32{11}	Integer{3}	ID	Input{1}	Original{256}	Nothing
p2	String(16)	VarWChar{202}	苗字	Input{1}	Original{256}	Nothing
p3	String(16)	VarWChar{202}	苗字	Input{1}	Original{256}	Nothing
p4	String(16)	VarWChar{202}	名前	Input{1}	Original{256}	Nothing
p5	String(16)	VarWChar{202}	名前	Input{1}	Original{256}	Nothing
p6	Decimal(7)	Numerid{113}	年齢	Input{1}	Original{256}	Nothing
p7	Decimal(7)	Numerid{113}	年齢	Input{1}	Original{256}	Nothing

これを見ると、引数１と引数２は同じ値になり、しかも、苗字と名前に関してはString型と1の比較を行っていることになります。
Dim Str1 As String = "山田"
If Str1 = 1 Then
 〜省略〜
End If
とすると: 'String "山田" から型 'Double' への変換は無効です。'
となります。
SQL文では、文字列と数値が比較できるのでしょうか？
お手を煩わせます。

■No35088に返信(Wanさんの記事)
> 'UPD_ Cmd.CommandText ：UPDATE 既存テーブル SET 苗字 = ?, 名前 = ?, 年齢 = ? 
> WHERE ((ID = ?) AND 
> ((? = 1 AND 苗字 IS NULL) OR (苗字 = ?)) AND 
> ((? = 1 AND 名前 IS NULL) OR (名前 = ?)) AND 
> ((? = 1 AND 年齢 IS NULL) OR (年齢 = ?)))

No35089 の機能は、SourceColumnNullMapping プロパティによって制御されています。

Dim sb As New System.Text.StringBuilder()
sb.AppendLine($"UpdateCommand のパラメータ数={UPD_Cmd.Parameters.Count}")
For Each p As OleDbParameter In UPD_Cmd.Parameters
    sb.Append($"{p.ParameterName,-4}{vbTab}")
    sb.Append($"{p.SourceVersion,-8}{vbTab}")
    sb.Append($"{If(p.SourceColumnNullMapping, "T", "F")}{vbTab}")
    sb.Append($"{p.OleDbType,-8}{vbTab}")
    sb.AppendLine($"{p.SourceColumn}")
Next
Debug.WriteLine(sb.ToString())

上記を実行すると、このような表が得られます。
p1,p5,p6 の違いに着目してみてください。

================================================
UpdateCommand のパラメータ数=10
p1    Current    F   VarWChar  苗字
p2    Current    F   VarWChar  名前
p3    Current    F   Numeric   年齢
p4    Original   F   Integer   ID
p5    Original   T   Integer   苗字
p6    Original   F   VarWChar  苗字
p7    Original   T   Integer   名前
p8    Original   F   VarWChar  名前
p9    Original   T   Integer   年齢
p10   Original   F   Numeric   年齢
================================================

Original は SELECT した時点の元の値を意味し、
Current は、これから反映させたい編集後の値です。

「p5 と p6」「p7 と p8」「p9 と p10」では、
SourceColumn は同じですが、
SourceColumnNullMapping が異なっていますよね。これが
　(? = 1 AND {SourceColumn} IS NULL) OR ({SourceColumn} = ?)
の正体となります。


--- 以下蛇足 ---
> インスタンス名	Access2010
Access 2010 世代のプロバイダー名は、本来は
"Microsoft.ACE.OLEDB.12.0" ですね。もちろん
"Microsoft.ACE.OLEDB.16.0" からでもアクセス可能ですが。


> Dim oledb As String = "Microsoft.ACE.OLEDB.16.0;"
oledb という変数名を付けて後で、それと同名の
> Dim Cn As New OleDb.OleDbConnection(…
な OleDb 名前空間を記述されていますね。
名前が被って分かりにくくなりませんか?

それ以外の
> Dim Da As New OleDbDataAdapter(…
> Dim builder As OleDbCommandBuilder = …
では、OleDb. が無い状態にそろえてあるのに対し、
oledb 変数名が必要なところだけが意図的に
OleDb. 付きの表記なので、ちょっと混乱しそうです。
もちろん、文法的には問題ないのですけれども。


> Dim Cn As New OleDb.OleDbConnection($"Provider={oledb} Data Source={acfile}")
プロバイダー名にセミコロンを入れるのは不自然ですね。
　Dim oledb As String = "Microsoft.ACE.OLEDB.16.0;"
　$"Provider={oledb} Data Source={acfile}"
よりは
　Dim oledb As String = "Microsoft.ACE.OLEDB.16.0"
　$"Provider={oledb};Data Source={acfile}"
の方が好ましいですよ。他のパラメーターもセミコロン区切りなので。

実際のところ、接続文字列は
　Dim csb As New OleDbConnectionStringBuilder()
　csb.Provider = "Microsoft.ACE.OLEDB.16.0"
　csb.DataSource = "D:\データベース勉強用DB\INSERT文.accdb"
　Dim Cn As New OleDbConnection(csb.ConnectionString)
のようにして組み立てることもできるのですが、この際に
　csb.Provider = "Microsoft.ACE.OLEDB.16.0;"
としてしまうと、正しく接続できなくなります。


> Dim Da As New OleDbDataAdapter("SELECT * FROM 既存テーブル", Cn)
[既存テーブル] なのですね。冒頭の記述から [Test] かと誤解してました。

> (Accessのテーブル構成)
> インスタンス名	Access2010
> データベース名	データベース勉強用DB
> 論理テーブル名	Test
> 物理テーブル名	INSERT文.accdb

■No35091に追記(魔界の仮面弁士の記事)
> No35089 の機能は、SourceColumnNullMapping プロパティによって制御されています。

おぉ。追加説明のコードを書いているうちに、
ピンポイントでその点についての追加質問が投稿されていた…！


SQL における「列名 = 値」という記述について考えてみます。

SET などの『代入処理』の場合は、
値が null/非null いずれでも、「列名 = 値」と書けます。

しかし、WHERE などの『比較処理』の場合は、
「列名 = NULL」では TRUE 判定されないため、
「列名 = 非NULL値」と「列名 IS NULL」を使い分けねばなりません。
そのための仕組みです。


ついでなので、DELETE と INSERT のケースも載せておきます。

DeleteCommand のパラメータ数=7
p1      Original    F   Integer     ID
p2      Original    T   Integer     苗字
p3      Original    F   VarWChar    苗字
p4      Original    T   Integer     名前
p5      Original    F   VarWChar    名前
p6      Original    T   Integer     年齢
p7      Original    F   Numeric     年齢


InsertCommand のパラメータ数=3
p1  	Current 	F	VarWChar	苗字
p2  	Current 	F	VarWChar	名前
p3  	Current 	F	Numeric 	年齢


DataTable 内のデータは、DataRowVersion によってバージョン管理されており、
SELECT 直後の値(Original)と
編集結果を考慮した現在値(Current)の 2 種類を持ちます。
※ DataRow の RowState プロパティも参照


Original なパラメーターは、WHERE 句のために使われます。
INSERT の場合は WHERE が無いので、Current のみです。

逆に DELETE の場合は、現在値が存在しないため Current がなく
Original だけになります。

そして UPDATE の場合は、SET 句用の Current と
WHERE 句用の Original の両方があるというわけです。