■No35212に返信(ゆりりんさんの記事)
> 何も印刷されなくなってしまいました。

『フォントサイズ』の指定、および、『描画位置の座標』は正しいですか?

MM_TEXT から MM_LOMETRIC に変更したのであれば、フォントサイズだけでは無く
描画座標も MM_LOMETRIC 単位系で計算しなおす必要があります。


描画位置を変更したくない場合は、GetMapMode と SetMapMode をペアで使うようにして、
フォント作成後、描画時に座標系を元に戻してみてください。先の私の回答では、フォントを
「MM_LOMETRIC あるいは MM_HIMETRIC で生成する」とは書きましたが、
「MM_LOMETRIC あるいは MM_HIMETRIC で描画する」とは書いていません。


MapMode は 1〜8 の 8 種類あります。指定するモードによっては、
単位だけでなく軸の向きも変化していることに注意してください。

　(A) X 座標が右に、Y 座標が上に向かって増加していくもの
　(B) X 座標が右に、Y 座標が下に向かって増加していくもの
　(C) SetWindowExtEx() / SetViewportExtEx() で単位、向き、スケーリングを指定するもの
　http://www.kumei.ne.jp/c_lang/sdk/sdk_55.htm
　http://yamatyuu.net/computer/program/sdk/gdi/mapmode/index.html

---

(A) 右向き、上向きな MapMode
　1 … MM_TEXT。1 デバイスピクセル単位の物理座標系。
　6 … MM_TWIPS。0.05ポイント単位(1/1440インチ単位)の論理座標系。

(B) 右向き、下向きな MapMode
　2 … MM_LOMETRIC。0.1 ミリ単位の論理座標系。
　3 … MM_HIMETRIC。0.01 ミリ単位の論理座標系。
　4 … MM_LOENGLISH。0.01 インチ単位の論理座標系。
　5 … MM_HIENGLISH。0.001 インチ単位の論理座標系。

(C) 単位、向き、スケーリングを任意に指定できる MapMode
　7 … MM_ISOTROPIC。異方性ユーザー定義単位系。任意の単位、向き、スケーリングを持つ。
　8 … MM_ANISOTROPIC。等方性ユーザー定義単位系。X 軸と Y 軸の 1 単位が等しい。

■No35626に返信(HKaneさんの記事)
> 1行のみ、または、連続行選択のみを許し、
> 例えば10行あるデータで2行目と5行目のみの選択のような歯抜け選択を許さないようにする方法はあるでしょうか？

泥臭い方法しか思いつきませんでした。

Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        DataGridView1.AllowUserToAddRows = False
        DataGridView1.SelectionMode = DataGridViewSelectionMode.FullRowSelect
        DataGridView1.ColumnCount = 10
        DataGridView1.RowCount = 1000
    End Sub

    Private Sub DataGridView1_SelectionChanged(sender As Object, e As EventArgs) Handles DataGridView1.SelectionChanged
        Dim selectedRows = DataGridView1.SelectedRows.OfType(Of DataGridViewRow)().ToArray()
        Dim firstRow = selectedRows.FirstOrDefault()
        Dim lastRow = selectedRows.LastOrDefault()
        If If(firstRow, lastRow) Is Nothing Then
            Return
        End If
        Dim firstRowIndex = selectedRows.Min(Function(r) r.Index)
        Dim lastRowIndex = selectedRows.Max(Function(r) r.Index)
        If selectedRows.Length < (lastRowIndex - firstRowIndex) + 1 Then
            Dim unselectedRows = DataGridView1.Rows.Cast(Of DataGridViewRow)() _
                .Skip(firstRowIndex) _
                .Take(lastRowIndex - firstRowIndex + 1) _
                .Where(Function(r) Not r.Selected) _
                .ToArray()
            For Each row In unselectedRows
                row.Selected = True
            Next
        End If
    End Sub
End Class

■No35626に返信(HKaneさんの記事)
> DataGridViewで、
> SelectionMode = FullRowSelect
> MultiSelect = True
> の状態にすると、複数行選択が可能ですが、
> 1行のみ、または、連続行選択のみを許し、
> 例えば10行あるデータで2行目と5行目のみの選択のような歯抜け選択を許さないようにする方法はあるでしょうか？


DataGridView を継承したコントロールを作り、SetSelectedRowCore をオーバーライドして、すでに選択された行が存在する場合、上の行か下の行が選択状態かどうかをチェックするといいのでは。

Public Class DataGridViewEx
    Inherits DataGridView

    Protected Overrides Sub SetSelectedRowCore(rowIndex As Integer, selected As Boolean)
        If selected AndAlso SelectedRows.Count > 0 Then
            If Not IsRowSelected(rowIndex + 1) AndAlso Not IsRowSelected(rowIndex - 1) Then
                selected = False
            End If
        End If
        MyBase.SetSelectedRowCore(rowIndex, selected)
    End Sub

    Private Function IsRowSelected(rowIndex As Integer) As Boolean
        If rowIndex >= 0 AndAlso rowIndex < RowCount Then
            Return Rows(rowIndex).Selected
        End If
        Return False
    End Function

End Class