2024/03/21(Thu) 11:02:37 編集(投稿者)

■No35589に返信(うえしさんの記事)
> MenuStrip上のアイテムに設定したアクセスキーが、半角シフトの状態では正常に反応しますが、全角シフトの状態では全く反応しません。
> 市販のソフトに設定されているアクセスキーは正常に反応します。

メモ帳などで使われているメニューと、MenuStrip は別物です。
.NET には MainMenu というものがあります。
古い時代のものですから、拡張性がなく、今ではデザイナのツールボックスからも消えてしまいました。
次の様なコードで使用できます。

Public Class Form1

    Public Sub New()
        InitializeComponent()
        Dim mainMenu As New MainMenu
        Dim fileMenu As New MenuItem("ファイル(&F)")
        Dim exitMenuItem As New MenuItem("終了(&X)")
        fileMenu.MenuItems.Add(exitMenuItem)
        mainMenu.MenuItems.Add(fileMenu)
        Me.Menu = mainMenu
        AddHandler exitMenuItem.Click, AddressOf exitMenuItem_Click
    End Sub

    Private Sub exitMenuItem_Click(sender As Object, e As EventArgs)
        Close()
    End Sub

End Class

.NET Core 3.1 以降、使えなくなりますので、使わないほうがいいと思います。

■No35494に返信(ぱんださんの記事)
> pingのように結果がリアルタイム？で何度も返ってくる場合のサンプルコードを
> 知りたいです。

Process.StandardOutput は StreamReader です。
EndOfStream プロパティが True になるまで ReadLine を繰り返してください。

Using p As New Process
    p.StartInfo.FileName = Environment.GetEnvironmentVariable("ComSpec")
    p.StartInfo.UseShellExecute = False
    p.StartInfo.RedirectStandardOutput = True
    p.StartInfo.RedirectStandardInput = False
    p.StartInfo.CreateNoWindow = True
    p.StartInfo.Arguments = "/c ping 127.0.0.1"
    p.Start()
    Dim reader = p.StandardOutput
    Do Until reader.EndOfStream
        Dim buffer = reader.ReadLine()
        Console.WriteLine(buffer)
    Loop
    p.WaitForExit()
End Using
Console.WriteLine("何かキーを押すと終了します。")
Console.ReadKey()

早速の返信ありがとうございます。
おかげさまで以下のコードで実現できて助かりました。
これから少しづつ学んでいこうと思います。
ありがとうございました。

        Using p As New Process
            p.StartInfo.FileName = Environment.GetEnvironmentVariable("ComSpec")
            p.StartInfo.UseShellExecute = False
            p.StartInfo.RedirectStandardOutput = True
            p.StartInfo.RedirectStandardInput = False
            p.StartInfo.CreateNoWindow = True
            p.StartInfo.Arguments = "/c ping 127.0.0.1"
            p.Start()
            Dim reader = p.StandardOutput
            Do Until reader.EndOfStream
                Dim buffer = reader.ReadLine()
                '以下3行を追加
                Debug.Print(buffer)
                TextBox1.Text = TextBox1.Text & vbCrLf & buffer
                Me.Refresh()
            Loop
            p.WaitForExit()
        End Using

KOZさん

度々すみません。
以下のコードと添付写真の通り作成してみたのですが、
例えば添付写真のように途中でキャンセルする方法はありますか？
実行中は他のボタンも押せなくなってしまいます。
何度も申し訳ありませんが、可能でしたらサンプルコードを教えて
いただけましたら幸いです。
何卒よろしくお願いいたします。

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        'Process.StandardOutput は StreamReader です。
        'EndOfStream プロパティが True になるまで ReadLine を繰り返してください。

        Using p As New Process
            p.StartInfo.FileName = Environment.GetEnvironmentVariable("ComSpec")
            p.StartInfo.UseShellExecute = False
            p.StartInfo.RedirectStandardOutput = True
            p.StartInfo.RedirectStandardInput = False
            p.StartInfo.CreateNoWindow = True
            'p.StartInfo.Arguments = "/c ping 127.0.0.1"
            p.StartInfo.Arguments = "/c " & TextBox2.Text
            p.Start()
            Dim reader = p.StandardOutput
            Do Until reader.EndOfStream
                Dim buffer = reader.ReadLine()
                'Console.WriteLine(buffer)
                Debug.Print(buffer)
                TextBox1.Text = TextBox1.Text & vbCrLf & buffer
                Me.Refresh()
            Loop
            p.WaitForExit()
        End Using
        'Console.WriteLine("何かキーを押すと終了します。")
        'Console.ReadKey()
    End Sub

2023/08/23(Wed) 05:57:00 編集(投稿者)

■No35497に返信(ぱんださんの記事)

CTRL+C を送ってキャンセルでいいんですかね？

Imports System.Runtime.InteropServices

Public Class Form1

    Private cmdProcess As Process

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        If cmdProcess IsNot Nothing Then Return
        TextBox1.Clear()
        cmdProcess = New Process
        cmdProcess.StartInfo.FileName = Environment.GetEnvironmentVariable("ComSpec")
        cmdProcess.StartInfo.UseShellExecute = False
        cmdProcess.StartInfo.RedirectStandardOutput = True
        cmdProcess.StartInfo.RedirectStandardInput = False
        cmdProcess.StartInfo.CreateNoWindow = True
        cmdProcess.StartInfo.Arguments = "/c " & TextBox2.Text
        cmdProcess.Start()
        Task.Run(AddressOf ReadTask)
        Button1.Enabled = False
        Button2.Enabled = True
    End Sub

    Private Sub ReadTask()
        Dim reader = cmdProcess.StandardOutput
        Do Until reader.EndOfStream
            Dim buffer = reader.ReadLine()
            Invoke(Sub()
                       TextBox1.AppendText(vbCrLf & buffer)
                       Refresh()
                   End Sub)
        Loop
        cmdProcess.WaitForExit()
        cmdProcess.Dispose()
        cmdProcess = Nothing
        Invoke(Sub()
                   Button1.Enabled = True
                   Button2.Enabled = False
               End Sub)
    End Sub

    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        If AttachConsole(cmdProcess.Id) Then
            SetConsoleCtrlHandler(IntPtr.Zero, True)
            GenerateConsoleCtrlEvent(CTRL_C_EVENT, 0)
            cmdProcess.WaitForExit()
            SetConsoleCtrlHandler(IntPtr.Zero, False)
            FreeConsole()
        End If
    End Sub

    Private Const CTRL_C_EVENT = 0
    Private Const CTRL_BREAK_EVENT = 1

    <DllImport("Kernel32")>
    Private Shared Sub GenerateConsoleCtrlEvent(dwCtrlEvent As Integer, dwProcessGroupId As Integer)
    End Sub

    <DllImport("Kernel32")>
    Private Shared Function AttachConsole(dwProcessId As Integer) As Boolean
    End Function

    <DllImport("Kernel32")>
    Private Shared Function SetConsoleCtrlHandler(HandlerRoutine As IntPtr, add As Boolean) As Boolean
    End Function

    <DllImport("Kernel32")>
    Private Shared Function FreeConsole() As Boolean
    End Function

End Class

2023/08/23(Wed) 21:08:45 編集(投稿者)

KOZさん

早速ありがとうございます。

複雑な処理が必要なんですね！
サンプルコードを元に勉強していきたいと思います。
本当にどうもありがとうございました。

■No35467に返信(くるりさんの記事)
> 親コントロールと同色のReadonlyのTextboxを設置したいのですが、何か良い方法はあるでしょうか。

DrawToBitmap で bmp に描画して、GetPixel で色を取得するとか。

Public Class Form1

    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles MyBase.Shown
        Dim sz = TabPage1.Size
        Using bmp As New Bitmap(sz.Width, sz.Height)
            TabPage1.DrawToBitmap(bmp, New Rectangle(Point.Empty, sz))
            Dim bkColor = bmp.GetPixel(1, 1)
            TextBox1.BackColor = bkColor
        End Using
    End Sub

End Class