■No35177に返信(ま〜さんの記事)
> こんいちは
おはこんばんちは


> Labelで文字単位の反転文字をしたいのですが（特定の文字だけ協調したい）
> こんな事はRichTextで無いと無理なのでしょうか？

WinForms だと、LinkLabel で代用するとかですかね…。
本来の目的とは違いますけれども。

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    LinkLabel1.Text = "こんいちは → こんにちは"
    LinkLabel1.Links.Add(2, 1).Description = "間違い"
    LinkLabel1.Links.Add(5, 3).Enabled = False
    LinkLabel1.Links.Add(10, 1).Visited = True
    LinkLabel1.ForeColor = Color.Black
    LinkLabel1.LinkColor = Color.Red
    LinkLabel1.DisabledLinkColor = Color.Blue
    LinkLabel1.VisitedLinkColor = Color.Green
    LinkLabel1.LinkBehavior = LinkBehavior.NeverUnderline
End Sub


素の Label で実装するなら、継承して OnPaint をオーバーライドするか
Label の Paint イベントを使うぐらいでしょうか。


Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    'Label1.Text = "こんいちは"
    Label1.Font = New Font("ＭＳ ゴシック", 18.0F)
    Label1.Text = "こん　ちは"
    Label1.ForeColor = Color.Navy
End Sub

Private Sub Label1_Paint(sender As Object, e As PaintEventArgs) Handles Label1.Paint
    If Label1.UseCompatibleTextRendering Then
        e.Graphics.DrawString("　　い　　", Label1.Font, Brushes.Crimson, e.ClipRectangle)
    Else
        TextRenderer.DrawText(e.Graphics, "　　い　　", Label1.Font, e.ClipRectangle, Color.Crimson)
    End If
End Sub


WPF の Label なら Label.Content に TextBlock を置いてみるとか。

<Label HorizontalAlignment="Left" VerticalAlignment="Top">
  <TextBlock>
    <Run>こん</Run><Run Foreground="Red">い</Run><Run>ちは</Run>
  </TextBlock>
</Label>

■No35181に返信(魔界の仮面弁士さんの記事)
> 本当は、そもそもフォーカスを受け取らないようにするか、
> あるいはせめて、前回フォーカスのあったコントロールに戻す方が
> 望ましいのですけれど…ひとまず手抜き実装ということで。

RichTextBox を非表示にして親に描画するとか。

Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        RichTextBox1.Visible = False
        RichTextBox1.Text = "こんにちは！"
        RichTextBox1.SelectionStart = 5
        RichTextBox1.SelectionLength = 1
        RichTextBox1.SelectionColor = Color.White
        RichTextBox1.SelectionBackColor = Color.Red
    End Sub

    Private Sub Form1_Paint(sender As Object, e As PaintEventArgs) Handles MyBase.Paint
        Using bmp As New Bitmap(RichTextBox1.Width, RichTextBox1.Height)
            RichTextBox1.DrawToBitmap(bmp, New Rectangle(New Point(0, 0), RichTextBox1.Size))
            e.Graphics.DrawImage(bmp, RichTextBox1.Location)
        End Using
    End Sub

End Class