2022/12/09(Fri) 04:27:45 編集(投稿者)

■No35275に返信(ま〜さんの記事)
>>高 DPI 環境で実行している場合は、ズレる可能性がありますね。
> まさにこれが原因でした。凄いです感激です。

これ動きますか？
ちょっと問題があって、画像を縮小するせいか、少しぼやけた感じになります。
,NET Framework 4.7 以上なら RichTextBox の DrawToBitmap を使ったほうがいいかもしれません。

Imports System.Runtime.InteropServices

Public Class Form1

    <DllImport("User32.dll")>
    Public Shared Function LogicalToPhysicalPointForPerMonitorDPI(ByVal hwnd As IntPtr, ByRef point As Point) As Boolean
    End Function

    Private Shared Function LogicalToPhysicalRectangleForPerMonitorDPI(ByVal hwnd As IntPtr, ByVal r As Rectangle) As Rectangle
        Dim p1 As Point = r.Location
        Dim p2 As Point = New Point(r.Right, r.Bottom)
        LogicalToPhysicalPointForPerMonitorDPI(hwnd, p1)
        LogicalToPhysicalPointForPerMonitorDPI(hwnd, p2)
        Return Rectangle.FromLTRB(p1.X, p1.Y, p2.X, p2.Y)
    End Function

    Private Function LogicalToPhysicalRectangleForPerMonitorDPI(ByVal r As Rectangle) As Rectangle
        Return LogicalToPhysicalRectangleForPerMonitorDPI(Handle, r)
    End Function

    Public Sub New()
        InitializeComponent()
        PictureBox1.SizeMode = PictureBoxSizeMode.Zoom
        PictureBox1.Size = RichTextBox1.Size
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim rectangle1 = RectangleToScreen(RichTextBox1.Bounds)
        Dim rectangle2 = LogicalToPhysicalRectangleForPerMonitorDPI(rectangle1)
        Dim bmp = New Bitmap(rectangle2.Width, rectangle2.Height)
        Using g = Graphics.FromImage(bmp)
            g.CopyFromScreen(rectangle2.Location, Point.Empty, rectangle2.Size)
        End Using
        If PictureBox1.Image IsNot Nothing Then
            PictureBox1.Image.Dispose()
        End If
        PictureBox1.Image = bmp
    End Sub

End Class

■No35280に返信(ま〜さんの記事)
> こんにちは、体調を崩して回答が遅れました。すみません。

お大事に。

> ですがTabPage環境化ではズレました。
> Parentをと思って色々やってみましたが中々上手くいかずTabPage下の座標知る方法はないのでしょうか？

むむむ、やっかいですね高DPI。
スクリーン座標を取るのが目的でないなら、以下のコードでキャプチャはできると思います。

Imports System.Runtime.InteropServices

Public Class Form1

    Public Sub New()
        InitializeComponent()
        PictureBox1.SizeMode = PictureBoxSizeMode.Zoom
        PictureBox1.Size = RichTextBox1.Size
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim bmp = CreateBitmapFromControl(RichTextBox1)
        If PictureBox1.Image IsNot Nothing Then
            PictureBox1.Image.Dispose()
        End If
        PictureBox1.Image = bmp
    End Sub

    Private Const SRCCOPY As Integer = &HCC0020

    <DllImport("User32.dll")>
    Private Shared Function GetWindowDC(hWnd As IntPtr) As IntPtr
    End Function

    <DllImport("user32.dll")>
    Private Shared Function ReleaseDC(hWnd As IntPtr, hDC As IntPtr) As Boolean
    End Function

    <DllImport("gdi32.dll")>
    Private Shared Function BitBlt(hdcDest As IntPtr,
                                   nXDest As Integer, nYDest As Integer,
                                   nWidth As Integer, nHeight As Integer,
                                   hdcSrc As IntPtr,
                                   nXSrc As Integer, nYSrc As Integer,
                                   dwRop As Integer) As Boolean
    End Function

    Private Shared Function CreateBitmapFromControl(con As Control) As Bitmap
        Dim cs = con.Size
        Dim bmp As New Bitmap(cs.Width, cs.Height)
        Using g = Graphics.FromImage(bmp)
            Dim hdcDest = g.GetHdc()
            Dim hdcSrc = GetWindowDC(con.Handle)
            BitBlt(hdcDest, 0, 0, cs.Width, cs.Height, hdcSrc, 0, 0, SRCCOPY)
            ReleaseDC(con.Handle, hdcSrc)
            g.ReleaseHdc()
        End Using
        Return bmp
    End Function

End Class

■No35212に返信(ゆりりんさんの記事)
> 何も印刷されなくなってしまいました。

『フォントサイズ』の指定、および、『描画位置の座標』は正しいですか?

MM_TEXT から MM_LOMETRIC に変更したのであれば、フォントサイズだけでは無く
描画座標も MM_LOMETRIC 単位系で計算しなおす必要があります。


描画位置を変更したくない場合は、GetMapMode と SetMapMode をペアで使うようにして、
フォント作成後、描画時に座標系を元に戻してみてください。先の私の回答では、フォントを
「MM_LOMETRIC あるいは MM_HIMETRIC で生成する」とは書きましたが、
「MM_LOMETRIC あるいは MM_HIMETRIC で描画する」とは書いていません。


MapMode は 1〜8 の 8 種類あります。指定するモードによっては、
単位だけでなく軸の向きも変化していることに注意してください。

　(A) X 座標が右に、Y 座標が上に向かって増加していくもの
　(B) X 座標が右に、Y 座標が下に向かって増加していくもの
　(C) SetWindowExtEx() / SetViewportExtEx() で単位、向き、スケーリングを指定するもの
　http://www.kumei.ne.jp/c_lang/sdk/sdk_55.htm
　http://yamatyuu.net/computer/program/sdk/gdi/mapmode/index.html

---

(A) 右向き、上向きな MapMode
　1 … MM_TEXT。1 デバイスピクセル単位の物理座標系。
　6 … MM_TWIPS。0.05ポイント単位(1/1440インチ単位)の論理座標系。

(B) 右向き、下向きな MapMode
　2 … MM_LOMETRIC。0.1 ミリ単位の論理座標系。
　3 … MM_HIMETRIC。0.01 ミリ単位の論理座標系。
　4 … MM_LOENGLISH。0.01 インチ単位の論理座標系。
　5 … MM_HIENGLISH。0.001 インチ単位の論理座標系。

(C) 単位、向き、スケーリングを任意に指定できる MapMode
　7 … MM_ISOTROPIC。異方性ユーザー定義単位系。任意の単位、向き、スケーリングを持つ。
　8 … MM_ANISOTROPIC。等方性ユーザー定義単位系。X 軸と Y 軸の 1 単位が等しい。