• 日時を表す文字列をDateTimeオブジェクトに変換する
  • Parseメソッドで変換する
  • カルチャを指定して変換する
  • 和暦の文字列を変換する
  • Parseメソッドで変換できない書式の文字列をParseExactメソッドで変換する
  • ParseやParseExactで変換できるか試してみる

• この記事への評価、コメント

日時を表す文字列をDateTimeオブジェクトに変換する

ここでは、「1992/2/16 12:15:12」のように日時を表す文字列をDateTimeオブジェクトに変換する方法を説明します。

DateTimeだけでなく、DateTimeOffsetへの変換に関する説明も一部含まれています。

Parseメソッドで変換する

単純な変換であれば、DateTime.Parseメソッドで簡単に出来ます。説明も不要と思いますので、具体例をご覧ください。

'DateTime値に変換する文字列
Dim s1 As String = "1992/2/16 12:15:12"
'文字列をDateTime値に変換する
Dim dt1 As DateTime = DateTime.Parse(s1)
'結果を表示する
Console.WriteLine(dt1)
'1992/02/16 12:15:12

'時間が省略されている
Dim s2 As String = "1992/2/16"
Dim dt2 As DateTime = DateTime.Parse(s2)
Console.WriteLine(dt2)
'1992/02/16 0:00:00
'時間を省略すると、「0:00:00」となる

'日付が省略されている
Dim s3 As String = "12:15:12"
Dim dt3 As DateTime = DateTime.Parse(s3)
Console.WriteLine(dt3)
'2003/03/12 12:15:12
'日付を省略すると、現在の日付となる

//DateTime値に変換する文字列
string s1 = "1992/2/16 12:15:12";
//文字列をDateTime値に変換する
DateTime dt1 = DateTime.Parse(s1);
//結果を表示する
Console.WriteLine(dt1);
//1992/02/16 12:15:12

//時間が省略されている
string s2 = "1992/2/16";
DateTime dt2 = DateTime.Parse(s2);
Console.WriteLine(dt2);
//1992/02/16 0:00:00
//時間を省略すると、「0:00:00」となる

//日付が省略されている
string s3 = "12:15:12";
DateTime dt3 = DateTime.Parse(s3);
Console.WriteLine(dt3);
//2003/03/12 12:15:12
//日付を省略すると、現在の日付となる

カルチャを指定して変換する

上記の方法では、現在のカルチャを使用して変換を行います。もし特定のカルチャに独特の書式（フォーマット）で書かれた文字列をDateTime値に変換するならば、変換に使用するカルチャを2番目のパラメータに指定できます。このパラメータの型はIFormatProviderですが、通常ここにはCultureInfoかDateTimeFormatInfoオブジェクトを指定します。

2番目のパラメータにIFormatProviderを指定したときは、3番目のパラメータにDateTimeStyles列挙体も指定します。これによって、世界協定時刻(UTC)に変換するかや、空白文字を無視するか、文字列に日付が含まれていないときにグレゴリオ暦の1年1月1日にするかなどを指定できます。

DateTimeStyles列挙体の値には、以下のようなものがあります（説明は、MSDNからの抜粋です）。なお説明の中にある「DateTimeFormatInfo」というのは、2番目のパラメータに指定したDateTimeFormatInfoオブジェクト（または、CultureInfoオブジェクトのDateTimeFormatプロパティ）のことです。

以下に、ja-JPカルチャで、現地時間として、文字列をDateTime値に変換する例を示します。

'DateTime値に変換する文字列
Dim s1 As String = "1992年2月16日 12時15分12秒"

'ja-JPカルチャで、現地時間として、文字列をDateTime値に変換する
Dim ci As New System.Globalization.CultureInfo("ja-JP")
Dim dt1 As DateTime = DateTime.Parse(s1, ci, _
    System.Globalization.DateTimeStyles.AssumeLocal)

'結果を表示する
Console.WriteLine("{0} ({1})", dt1, dt1.Kind)
'1992/02/16 12:15:12 (Local)

//DateTime値に変換する文字列
string s1 = "1992年2月16日 12時15分12秒";

//ja-JPカルチャで、現地時間として、文字列をDateTime値に変換する
System.Globalization.CultureInfo ci =
    new System.Globalization.CultureInfo("ja-JP");
DateTime dt1 = DateTime.Parse(s1, ci,
    System.Globalization.DateTimeStyles.AssumeLocal);

//結果を表示する
Console.WriteLine("{0} ({1})", dt1, dt1.Kind);
//1992/02/16 12:15:12 (Local)

和暦の文字列を変換する

ja-JPカルチャを使用すれば、和暦の文字列もDateTime値に簡単に変換できます。

Dim dt As New DateTime(2000, 5, 12, 20, 30, 15, 123)

'ja-JPカルチャで、現地時間として、文字列をDateTime値に変換する
Dim ci As New System.Globalization.CultureInfo("ja-JP")

'和暦を変換する
Dim dt1 As DateTime = DateTime.Parse("平成4年2月16日 12時15分12秒", ci, _
    System.Globalization.DateTimeStyles.AssumeLocal)

'年号（元号）が省略された1文字（明, 大, 昭, 平）やアルファベット(M, T, S, H)でもOK
Dim dt2 As DateTime = DateTime.Parse("H4年2月16日 12時15分12秒", ci, _
    System.Globalization.DateTimeStyles.AssumeLocal)

//ja-JPカルチャで、現地時間として、文字列をDateTime値に変換する
System.Globalization.CultureInfo ci =
    new System.Globalization.CultureInfo("ja-JP");

//和暦を変換する
DateTime dt1 = DateTime.Parse("平成4年2月16日 12時15分12秒", ci,
    System.Globalization.DateTimeStyles.AssumeLocal);

//年号（元号）が省略された1文字（明, 大, 昭, 平）やアルファベット(M, T, S, H)でもOK
DateTime dt2 = DateTime.Parse("H4年2月16日 12時15分12秒", ci,
    System.Globalization.DateTimeStyles.AssumeLocal);

和暦の変換はJapaneseCalendarを使って行われますが、JapaneseCalendarがサポートしている最も古い時刻は「1868/09/08 0:00:00」（明治1年9月8日 0時0分0秒）ですので、それ以前の時刻は変換できません。

Parseメソッドで変換できない書式の文字列をParseExactメソッドで変換する

変換元の文字列が独特の書式であったり、書式が不確定で多数の候補を考慮しなければならないなどのケースでは、DateTime.ParseExactメソッドを使用します。

ParseExactメソッドでは書式の定義を、カスタム日時書式指定文字列で行います。カスタム日時書式指定文字列については、「日時（DateTimeオブジェクト）を文字列に変換する」で説明しています。

以下に例を示します。変換する文字列の書式が一つに決まっている場合と、可能性のある書式が複数ある場合の2つの例を紹介しています。

'"Wed, 25 Dec 2002 13:32:22 +0900"をDateTime型に変更する
Dim str As String = "Wed, 25 Dec 2002 13:32:22 +0900"

'文字列の書式が一つに決まっている時
'ここでは"ddd, d MMM yyyy HH':'mm':'ss zzz"
Dim dt1 As DateTime = DateTime.ParseExact(str, _
                "ddd, d MMM yyyy HH':'mm':'ss zzz", _
                System.Globalization.DateTimeFormatInfo.InvariantInfo, _
                System.Globalization.DateTimeStyles.None)
Console.WriteLine(dt1)
'"2002/12/25 13:32:22"と表示される

'文字列の書式に複数の可能性がある時
'"ddd, d MMM yyyy HH':'mm':'ss zzz"の他にも"r"も考慮する
'dateTimeStringが"Wed, 25 Dec 2002 13:32:22 GMT"などでも変換されるようになる
Dim expectedFormats As String() = {"ddd, d MMM yyyy HH':'mm':'ss zzz", "r"}
Dim dt2 As DateTime = DateTime.ParseExact(str, _
                expectedFormats, _
                System.Globalization.DateTimeFormatInfo.InvariantInfo, _
                System.Globalization.DateTimeStyles.None)
Console.WriteLine(dt2)
'"2002/12/25 13:32:22"と表示される

//"Wed, 25 Dec 2002 13:32:22 +0900"をDateTime型に変更する
string str = "Wed, 25 Dec 2002 13:32:22 +0900";

//文字列の書式が一つに決まっている時
//ここでは"ddd, d MMM yyyy HH':'mm':'ss zzz"
DateTime dt1 = System.DateTime.ParseExact(str,
            "ddd, d MMM yyyy HH':'mm':'ss zzz",
            System.Globalization.DateTimeFormatInfo.InvariantInfo,
            System.Globalization.DateTimeStyles.None);
Console.WriteLine(dt1);
//"2002/12/25 13:32:22"と表示される

//文字列の書式に複数の可能性がある時
//"ddd, d MMM yyyy HH':'mm':'ss zzz"の他にも"r"も考慮する
//dateTimeStringが"Wed, 25 Dec 2002 13:32:22 GMT"などでも変換されるようになる
string[] expectedFormats = { "ddd, d MMM yyyy HH':'mm':'ss zzz", "r" };
DateTime dt2 = System.DateTime.ParseExact(str,
            expectedFormats,
            System.Globalization.DateTimeFormatInfo.InvariantInfo,
            System.Globalization.DateTimeStyles.None);
Console.WriteLine(dt2);
//"2002/12/25 13:32:22"と表示される

ParseやParseExactで変換できるか試してみる

指定した文字列がParseやParseExactで変換できなかった場合は、例外がスローされます。例外をスローさせずにDateTimeに変換できるかを確かめるには、DateTime.TryParseやTryParseExactメソッドを使います。これらについて詳しくは、「文字列が日付型(DateTime)に変換できるか調べる」で説明します。

• 参考：
• 日付と時刻文字列の解析

• 関連：
• 日時（DateTimeオブジェクト）を文字列に変換する
• 文字列が日付型(DateTime)に変換できるか調べる

• 履歴：
• 2011/7/13 「カルチャを指定して変換する」を追加。その他書きなおし。
• 2011/10/31 和暦を変換する例を追加。